件名と内容が何も無いメールを自動的に迷惑メールのフォルダへ振り分ける方法
ツール⇒マクロ⇒Visual Basic Editorを開く
ThisOutlookSession に下記のコードを貼り付ける
Dim WithEvents objInboxItems As Outlook.Items 'イベント駆動のためのオブジェクト
Dim objDestinationFolder As Outlook.MAPIFolder '移動先フォルダ
' OutLook起動時に、このルールを有効にします。
Private Sub Application_Startup()
StartRule
End Sub
' ルールの有効化
Sub StartRule()
Dim objNameSpace As Outlook.NameSpace
Dim objInboxFolder As Outlook.MAPIFolder
Set objNameSpace = Application.Session
Set objInboxFolder = objNameSpace.GetDefaultFolder(olFolderInbox) '受信トレイのフォルダ
Set objInboxItems = objInboxFolder.Items '受信トレイのアイテムを関連付け
Set objDestinationFolder = objNameSpace.GetDefaultFolder(olFolderJunk) '迷惑メールのフォルダ
End Sub
' ルールの無効化
Sub StopRule()
Set objInboxItems = Nothing
End Sub
' イベント駆動型の処理ルーチンです
Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
'件名・内容がブランクを指定フォルダに移動
If Item.Body = "" And Item.Subject = "" Then
Item.Move objDestinationFolder
End If
End Sub
動かすためには、デジタル署名をするか、あるいは
ツール⇒マクロ⇒セキュリティーでセキュリティーレベルを「中」または「低」にする
デジタル署名の方法
すべてプログラム⇒Microsoft Office⇒Microsoft Office ツール⇒VBA プロジェクトのデジタル署名をクリックしてインストール
署名してOKをクリック
先ほどの Visual Basic Editor を開き、
ツール⇒デジタル署名⇒選択をクリツク⇒証明書のプロパティーを表示しますをクリック⇒証明書のインストール⇒次へ、次へとクリックして行き、完了、OKをクリック